logo 【TeeChart Pro ActiveX教程】2018 我也要发布文档

TeeChart Pro ActiveX教程(十九):TeeChart工具集(四)


下载TeeChart Pro ActiveX最新版本

本文将续讲工具集中的画线工具、附加示例工具、甘特拖动工具和网格带工具。

一、画线工具

绘制线工具允许使用鼠标在图表上绘制,选择,拖动和删除完全可自定义的线条。

设计时:

Teechart

可以将绘制线工具设置为特定系列,也可以将调用与任何图表系列保持关联,也可以通过鼠标按钮将其设置为特定的鼠标按钮。笔配置线条本身的颜色,宽度,样式和可见性,而“Enable Drawing/启用绘图”和“Enable Select/启用选择”分别启用/禁用线条的绘制和选择。

运行时:

在运行时添加绘制线工具是一项简单的操作,如下例所示:

With TChart1
    .Tools.Add tcDrawLine
    With .Tools.Items(0)
        .Active = True
        With .asDrawLine
          .Button = mbLeft
          .EnableDraw = True
          .EnableSelect = True
          .Series = 0
          .Pen.Color = vbCyan
        End with
    End With
End With

二、附加图例工具

附加图例工具允许在图表画布上的任何位置绘制完全可自定义的附加图例。

设计时:

Teechart

运行时:

附加图例工具必须设置为特定系列才能显示。该编辑图例按钮可以存取传奇编辑器,允许附加的图例的风格,位置,标志,格式,文本,渐变和阴影来进行配置。

Private Sub Form_Load()
With TChart1
    .AddSeries scBar
    .Series(0).FillSampleValues 6
    .AddSeries scBar
    .Series(1).FillSampleValues 6
    .Legend.LegendStyle = lsValues
    .Environment.InternalRepaint
    .Tools.Add tcExtraLegend
    With .Tools.Items(0).asExtraLegend
        .Series = TChart1.Series(1)
        .Legend.CustomPosition = True
        .Legend.Left = TChart1.Legend.ShapeBounds.Left
        .Legend.Top = TChart1.Legend.ShapeBounds.Bottom + 10
    End With
End With
End Sub

三、甘特拖动工具

甘特拖动工具可以拖动和/或调整甘特系列的条形。

设计时:

Teechart

甘特拖曳工具必须设置为特定的甘特系列才能显示。像素调整大小容差指定甘特图栏移动/调整大小的像素的最小数量,允许拖动启用/禁用甘特图栏的拖动,允许调整大小启用/禁用甘特图栏的大小调整,而光标设置将在各自的业务。

运行时:

在运行时添加额外的图例工具是一项简单的操作,如下例所示:

Private Sub Form_Load()
TChart1.Aspect.View3D = False
TChart1.AddSeries scGantt
TChart1.Series(0).XValues.Order = loNone

With TChart1.Series(0)
    .asGantt.AddGantt DateSerial(2017, 4, 1), DateSerial(2017, 4, 10), 0, "A"
    .asGantt.AddGantt DateSerial(2017, 4, 5), DateSerial(2017, 4, 15), 1, "B"
    .asGantt.AddGantt DateSerial(2017, 4, 2), DateSerial(2017, 4, 8), 2, "C"
    .asGantt.AddGantt DateSerial(2017, 4, 9), DateSerial(2017, 4, 21), 3, "D"
    .Marks.Visible = True
    .Marks.ShadowSize = 0
    .Marks.Gradient.Visible = True
End With
 
TChart1.Axis.Bottom.SetMinMax DateSerial(2017, 4, 1), DateSerial(2017, 5, 1)
TChart1.Axis.Left.SetMinMax -2, 5
TChart1.Axis.Left.GridCentered = False
TChart1.Zoom.Enable = False
TChart1.Axis.Bottom.Increment = TChart1.GetDateTimeStep(dtOneDay)
TChart1.Axis.Bottom.Labels.Angle = 90
TChart1.Axis.Bottom.Labels.DateTimeFormat = "dd-mmm"
TChart1.Tools.Add tcGantt
TChart1.Tools.Items(0).asGantt.Series = TChart1.Series(0)
TChart1.Tools.Items(0).Active = True
End Sub
 
Private Sub TChart1_OnGanttToolDragBar(ByVal Tool As Long, ByVal GanttBar As Long)
With TChart1.Tools.Items(0).asGantt.Gantt
    Label1.Caption = FormatDateTime(.StartValues.Value(GanttBar)) + " - " + _
                    FormatDateTime(.EndValues.Value(GanttBar))
End With
End Sub
 
Private Sub TChart1_OnGanttToolResizeBar(ByVal Tool As Long, ByVal GanttBar As Long, ByVal BarPart As TeeChart.EGanttToolPartBar)
With TChart1.Tools.Items(0).asGantt.Gantt
    Label1.Caption = FormatDateTime(.StartValues.Value(GanttBar)) + " - " + _
                    FormatDateTime(.EndValues.Value(GanttBar))
End With
End Sub
 
Private Sub TChart1_OnGetSeriesMark(ByVal SeriesIndex As Long, ByVal ValueIndex As Long, MarkText As String)
Select Case ValueIndex
    Case 0: MarkText = "John"
    Case 1: MarkText = "Ann"
    Case 2: MarkText = "David"
    Case 3: MarkText = "Carol"
End Select
End Sub
 
Private Sub TChart1_OnMouseUp(ByVal Button As TeeChart.EMouseButton, ByVal Shift As TeeChart.EShiftState, ByVal x As Long, ByVal y As Long)
    Label1.Caption = ""
End Sub

四、网格带工具

网格带工具为定义的轴的网格添加完全可配置的颜色带。

设计时:

Teechart

Grid Band Tool必须与指定的Axis相关联。波段1和波段2定义两个波段的笔刷特征,而背面定义背面颜色,通过波段是否具有图案化笔刷来显示。透明度设置每个相应乐队的透明度级别。

运行时:

在运行时添加网格带工具是一项简单的操作,如下例所示:

Private Sub Form_Load()
With TChart1
    .AddSeries scBar
    .Series(0).FillSampleValues 6
    
    .Tools.Add tcGridBand
    With .Tools.Items(0).asGridBand
        .Axis = TChart1.Axis.Left
        .Band1.Color = vbGreen
        .Band2.Color = vbBlue
    End With
End With
End Sub

下载TeeChart Pro ActiveX最新版本

购买TeeChart Pro AciveX正版授权,请点击“咨询在线客服”哟!

慧都315特惠