一、创建组件

　　从应用程序员的角度，即从某些使用组件去创建应用程序的人的角度看，组件是你能从组件板上选取，作为正在开发的应用程序的一部分，并编写事件处理代码使之成为专用。对一个组件开发者，DELPHI组件是一个直接地或间接地从TCOMPONENT派生的对象PASCAL类。

　　用DELPHI成功地开发和综合专用组件的关键是，它能够服从界面的各种需要和习惯以及DELPHI环境所期望组件的行为。

　　专用组件是一个对象PASCAL类，这个对象类是TCOMPONENT的后代，这使它本身就服从基本需要的大部分。例如，它给新组件出现在组件板上的能力，并且有能力与窗体设计者(FORM DESIGNEER)和对象检查器(OBJECT INSPECTOR)相互作用。可是，除了这些基本功能外，组件还可以定义任意复杂的行为和可以显示任意丰富的属性集给组件用户或应用程序员。这些对组件的标准及基本行为的扩充是组件编写者的责任。

　　要记住，有关专用组件最重要的事情是你可以用不同的方法来制作组件。几乎每一个做好的组件在设计和运用时通过它的属性和事件允许某中程度的专门化。但是，不可避免，你将触及到有关每个组件的限制或缺点。实际上，你需要一种特殊的组件编写者并没有预见的行为，给组件扩展新能力。或者，你需要使组件做某些根本不同的，在开始设计时并没有决定要做的事情。

　　二、扩展已有专用组件

　　在DELPHI中创建新组件的最容易的方法是通过对已存在组件类派生。你能使用任何DELPHI具有的标准组件作为派生你自己组件的基础。

　　例如，你可能要修改标准组件的某个特定属性的缺省值，使得这个缺省值在你将此组件放置到窗体上时自动地起作用。如果你发现你经常在运行时使用相同的方法调用序列去启动组件，或者，你发现只要你放置这个组件在窗体上后你就打算修改属性值，这可能是创建新组件的好机会，这个组件将通过缺省做所有事情，并且因此不需要将其放置在窗体上后做专门的初始化。

　　另外一个使你要定制一个已存在的可视控制的理由是，在某些标准窗口控制情形，例如编辑框和组合框，你可能想使用它们的一些非常规特征。为此，你必须在创建时设置专门的可选标志，以告知WINDOWS你需要建立一个专用控制，重载WINDOWS用于决定控制可视外观的创建属性。

　　三、创建从非专有类中派生一个新组件

　　创建一个“全新”可视组件仍然要从已存在VCL类中派生。扩展一个已有专用组件和创建一个全新组件之间的主要差别是，在后一种情况，你必须从一个非专用基类中派生，例如TWINCONTROL或TGRAPHICCONTRL，而不是从一个专用控制类派生，例如TLABLE，TMEMO或TCHECKBOX。

　　从非专用基类派生，确定将很多责任交到了组件创建者的手中。你必须关心组件与程序用户相互之间的细节和设计时界面的细节。

　　当你创建新组件时，你存取了一个对象的保护界面，这个界面是组件用户不可见的。对象PASCAL在类元素上定义4层保护，或成存取控制：私用的(private)、保护的(protected)、公共的(public)、和发表的(published)。通过指定保护层次，你能控制类元素被存取的上下文：谁可以从代码的那一块对它们存取。

　　组件用户可以存取实例的公共的和发表的元素。组件编写者，至少可以存取发表的，公共的和保护的元素。另外，如果派生类是与基础类被定义在同一个编译单元中，私有的元素也可以存取。

　　将类元素声明为私有的是隐藏它们的实现细节，与存取定义单元外的类实例的客户代码分开。将类元素作为私有的，使类的界面(发表的、公共的、保护的元素)与类的实现分开。这样，你可以在后来修改其实现而毫不影响客户代码。类用户自由地存取公共可用的元素而不必关心实现的细节。

　　可是，组件编写者的情况则多少有些进退两难。一方面，他们必须存取类实现的细节，以便修改或增强其父类提供的行为。另一方面，编写者是从一个已有组件派生新类，因此他也是组件的用户。从这个意义上讲，他应尽可能多地直接使用基础类，而不关心基础类实现的细节。

　　对象中这个两难问题是用提供保护界面解决的。存取控制的保护层恰恰给后继组件编写者足够的存取权，以便通过可能的继承方法扩展和修改组件。类对外部世界或对组件用户的封装仍然保持没有被析构，因此类封装的好处没有丢失。

　　当你派生新组件类时的主要考虑是决定哪个类是新类的父类。你必须研究已存在类的层次，以决定保护界面的哪些方面你要继承，而哪些方面你是不需要的。但是，一旦一个特殊类元素是公共的，它就不能成为私用的或保护的。类似地，一旦类元素已是发表的，它就保持发表状态，并且在所有那个类后代中都可以从对象视察器窗口可见。

　　四、创建组件示例

　　该例子说明的是：如何从一个已存在的专用类TDBText派生一个新组件类，通过增加BorderStyle属性以及重载PAINT事件产生一个类似TSTATICTEXT组件。具体实现如下：

　　首先选择Component/New Component； Ancestor Type：选择TDBText； Class Name：可以自己任意制定，这里为TDBStaticText；Palette Page：可以自己任意制定，这里为MyComponents；Unit File Name：可以自己任意制定，这里为c:my documents\dstatictext1.pas;Search path:为缺省值。选择 OK 之后，请输入以下源程序。

　　以上全部作完后保存你的新组件，选择Component/Install Component 并编译你的新组件。你将有一个名称为MyComponents 的新组件板，其中就有你刚制作的新组件TDBStaticText。

　　源程序清单：

　　unit DBStaticText;
　　interface
　　uses
　　Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
　　StdCtrls, DBCtrls;
　　type
　　TDBStaticBorderStyle = (sbsNone,sbsSingle,sbsSunken,sbsRaised);
　　TDBStaticText = class(TDBText)
　　private
　　{ Private declarations }
　　fBorderStyle : TDBStaticBorderStyle;
　　function GetBorderStyle:TDBStaticBorderStyle;
　　procedure SetBorderStyle(Value:TDBStaticBorderStyle);
　　protected
　　{ Protected declarations }
　　procedure Paint; override;
　　public
　　{ Public declarations }
　　published
　　{ Published declarations }
　　property BorderStyle : TDBStaticBorderStyle
　　read GetBorderStyle
　　write SetBorderStyle;
　　end;
　　procedure Register;
　　implementation
　　function TDBStaticText.GetBorderStyle:TDBStaticBorderStyle;
　　begin
　　Result := fBorderStyle
　　end;
　　procedure TDBStaticText.SetBorderStyle(Value:TDBStaticBorderStyle);
　　begin
　　if fBorderStyle <> Value then
　　begin
　　fBorderStyle := Value;
　　Invalidate;
　　end;
　　end;
　　procedure TDBStaticText.Paint;
　　var
　　Rect : TRect;
　　begin

　　// 设置颜色

　　Canvas.Brush.Color := Color;

　　// 获取长方形面积

　　Rect := GetClientRect();

　　// 用 DrawEdge API 画不同的边界

　　case fBorderStyle of
　　sbsSingle : DrawEdge(Canvas.Handle,Rect,EDGE_RAISED,BF_RECT+BF_FLAT);
　　sbsRaised : DrawEdge(Canvas.Handle,Rect,EDGE_RAISED,BF_RECT);
　　sbsSunken : DrawEdge(Canvas.Handle,Rect,EDGE_SUNKEN,BF_RECT);
　　end;

　　// 填充颜色

　　InflateRect(Rect,-2,-2);

　　Canvas.FillRect(Rect);

　　// 置文本对齐方式

　　case Alignment of
　　taLeftJustify : DrawText(Canvas.Handle,PChar(GetLabelText),-1,Rect,DT_LEFT + DT_VCENTER + DT_SINGLELINE);
　　taRightJustify : DrawText(Canvas.Handle,PChar(GetLabelText),-1,Rect,DT_RIGHT + DT_VCENTER + DT_SINGLELINE);
　　taCenter : DrawText(Canvas.Handle,PChar(GetLabelText),-1,Rect,DT_CENTER + DT_VCENTER + DT_SINGLELINE);
　　end;
　　end;
　　procedure Register;
　　begin
　　RegisterComponents('MyComponents', [TDBStaticText]);
　　end;
　　end.

　　以上代码在win98/Delphi5环境下调试通过。