Winsock  控件建立在  TCP、UDP  协议的基础上，完成与远程计算机的通信。即使对  TCP/IP不太熟悉的用户，使用该控件也可以在十几分钟内创建一个简单的客户机/服务器程序。下面我们对  Winsock  控件的事件、方法、属性按其在程序中出现的顺序分别作详细的介绍，以便更好地理解程序源代码。

下面是  Winsock  控件的相关属性，方法和事件。(略去一些暂用不到的)

*属性
-------------------------------------------------------------------------
LocalHostName | 本地机器名
LocalIP | 本地机器IP地址
LocalPort | 本地机器通信程序的端口(0<端口<65536)
RemoteHost | 远程机器名
RemotePort | 远程机器的通信程序端口
state | 连接的当前状态(文后有详细说明)
Protocal | 使用  TCP  或  UDP  协议(这里我们选‘0-sckTCPProtocal’)
--------------------------------------------------------------------------
*方法
--------------------------------------------------------------------------
Listen
Listen  方法用于服务器程序，等待客户访问。
格式：Winsock  对象 .listen
Connect
Connect  方法用于向远程主机发出连接请求
格式：Winsock  对象 .connect [远程主机  IP,远程端口]
Accept
Accept  方法用于接受一个连接请求
格式：Winsock  对象.accept Request ID
Senddata
此方法用于发送数据
格式：Winsock  对象 .senddata  数据
Getdata
用来取得接收到的数据
格式：Winsock  对象 .getdata  变量 [,数据类型 [,最大长度]]
Close
关闭当前连接
格式：Winsock  对象 .close
*事件
----------------------------------------------------------------------------
Close | 远程机器关闭连接时触发
Connect | 连接建立好，可以进行通信时触发(客户端)
ConnectRequest | 有请求连接到达时产生(服务器端)
DataArrival | 有数据到达时触发
Error | 发生错误时发生
SendProgress | 数据传送进度
-----------------------------------------------------------------------------

　　服务器程序的实现过程是：
　　（1）服务器程序必须设置好LocalPort  属性，作为侦听端口，该值为一个整数（只要是一个其它  TCP/IP  应用程序没有使用过的值即可）。
　　（2）使用  Listen  方法进入侦听状态，等待客户机程序的连接请求。
　　（3）客户机程序发出连接请求，使服务器程序产生  ConnectionRequest  事件，该事件得到一个参数  requestID。
　　（4）服务器程序用  Accept  方法接受客户机程序的  requested  请求。这样，服务器程序就可以用  SendData  方法发送数据了。Accept  方法必须用上一步得到的  requested  作为其参数。
　　（5）当服务器程序接收到数据时，产生  DataArrival  事件，参数  BytesTotal  包含接收到的数据字节数。在该事件中，可以用  GetData  方法接收数据。
　　（6）如果接受到  Close  事件，则用  Close  方法关闭  TCP/IP  连接。
　　客户机程序的实现过程是：
　　（1） 客户程序设置  Remotehost  属性，以便指定运行服务器程序的主机 名，该字符串可在“控制面板|网络|标识|计算机名”中查到。
　　（2） 设置  RemotePort  属性,以便指定服务器程序的侦听端口。
　　（3）使用  Connect  方法，向服务器提出连接请求。
　　（4）服务器接受客户机程序的请求，客户机程序产生  Connect  事件，就可以用  SendData  方法发送数据了。
　　（5）当客户机程序接收到数据时，产生  DataArrival  事件，参数  BytesTotal  包含接收到的数据字节数。在该事件中，可以用  GetData  方法接收数据。
　　（6）如果接受到  Close  事件，则用  Close  方法关闭连接。
　　Winsock  控件还有两个重要的属性，即  Protocol  和  State。Protocol  设定使用的协议是  TCP  还是  UDP：取值  sckTCPProtocol  表示  TCP, 取值  sckUDPProtocol  则表示  UDP。因为  Winsock  控件的缺省设置是  sckTCPProtocol，所以程序中并没有使用  Protocol  属性。State  属性反映的是当前  TCP/IP  的连接状态，取值如表1所示。
　　表1 Winsock  控件的  State  属性及其描述

　　先在一台计算机上运行服务器程序，此时窗口上只有一个“退出”按钮。 再在另一台计算机上运行客户机程序，在“连接”按钮右边的文本框中输入服务器的主机名后单击“连接”按钮。如果连接成功，则服务器和客户机程序窗口都会出现两个文本框。这时，两端都可以在上面的文本框中输入文字，这些文字会立即在下面的文本框中出现。
　　服务器程序使用的控件如下：
　　（1）Command1：退出按钮；
　　（2）textsend：发送数据文本框；
　　（3）Winsockserver： 服务器  Winsock；
　　（4）textget ：接收数据文本框。
　　服务器程序的界面如图所示。
　　服务器程序的源代码如下：
　　Private Sub Command1_Click()
　　End
　　End Sub
　　Private Sub Form_Load()
　　 textsend.Visible = False
　　 textget.Visible = False
　　 Winsockserver.LocalPort = 1001
　　 Winsockserver.Listen
　　End Sub

　　Private Sub textsend_Change()
　　Winsockserver.SendData textsend.Text
　　End Sub
　　Private Sub Winsockserver_Close()
　　Winsockserver.Close
　　End
　　End Sub
　　
　　Private Sub Winsockserver_ConnectionRequest(ByVal requestID As Long)
　　textsend.Visible = True
　　textget.Visible = True
　　If Winsockserver.State <> sckClosed Then Winsockserver.Close
　　Winsockserver.Accept requestID
　　End Sub
　　
　　Private Sub Winsockserver_DataArrival(ByVal bytesTotal As Long)
　　Dim tmpstr As String

　　Winsockserver.GetData tmpstr
　　textget.Text = tmpstr
　　End Sub

　　客户机程序使用的控件如下：
　　（1）Command1：退出按钮；
　　（2）Command2：连接按钮；
　　（3）Winsockclient：客户  Winsock；
　　（4）Text1：主机名文本框；
　　（5）Textsend：发送数据文本框；
　　（6）Textget：接收数据文本框； 　　
　　客户机程序的源代码如下：
　　Private Sub Command1_Click()
　　End
　　End Sub
　　Private Sub Command2_Click()
　　Winsockclient.Connect
　　End Sub
　　Private Sub Form_Load()
　　textsend.Visible = False
　 textget.Visible = False
　　 Winsockclient.RemotePort = 1001
　　Winsockclient.RemoteHost = "sccdsz"
　　End Sub
　　Private Sub Text1_Change()
　　Winsockclient.RemoteHost = Text1.Text
　　End Sub
　　Private Sub textsend_Change()
　　Winsockclient.SendData textsend.Text
　　End Sub
　　Private Sub Winsockclient_Close()
　　 Winsockclient.Close
　　 End
　　End Sub
　　Private Sub winsockclient_Connect()
　　 textsend.Visible = True
　　 textget.Visible = True
　　 Command2.Visible = False
　　End Sub
　　Private Sub winsockclient_DataArrival(ByVal bytesTotal As Long)
　　Dim tmpstr As String
　　Winsockclient.GetData tmpstr
　　textget.Text = tmpstr
　　End Sub